LST   OFF

***********************
*                     *
* HELLFIRE CLUB BOOT0 *
* (C)1991 BY DECKARD  *
*                     *
***********************
*
* SECTEUR/PISTE CROISSANTS
*

* FONCTIONNEMENT:
*
* LDA#<ADR(-) DE LA TABLE
* LDX#>ADR(+) DE LA TABLE
* JMP READER0
*
* DESCRIPTIF DE LA TABLE:
*
* PISTE, BUF(+)-2, SECTEUR, NB SECT, JMP(+), JMP(-)

* UTILISATION PASSAGERE DE $EC/ED/EE/EF

WAIT     EQU   $FCA8
DRIVEOFF EQU   $C0E8
DRIVEON  EQU   $C0E9
BOOT2    EQU   $FFFF
STROBE   EQU   $C010
SETVID   EQU   $FE93
SETKBD   EQU   $FE89
INIT     EQU   $FB2F
BOOT00   EQU   $C65C
PHASEOFF EQU   $C080
PHASEON  EQU   $C081
H0478    EQU   $0478
PISTE    EQU   $41
SECTEUR0 EQU   $3D
SECTEUR  EQU   $FF
BUFLOW   EQU   $26
BUFHIGH  EQU   $27
NB_SECTEUR EQU $FE
                          ;
         ORG   $0800

         HEX   01
                          ;
BOOT0    LDA   #$60
         STA   BOOT0
         LDA   #$00
         STA   H0478
         JSR   SETKBD
         JSR   SETVID
         JSR   INIT
         BIT   STROBE

         LDA   #<BOOT1INFO ; (-)
         LDX   #>BOOT1INFO ; (+)

         LST   ON
READER0  STA   $EC
         LST   OFF
         STX   $ED

         BIT   DRIVEON
         LDA   #$FF       ; TEMPO
         JSR   WAIT
         LDA   #$FF
         JSR   WAIT

         LDY   #0         ; MET EN PILE LES INFOS DE LA TABLE
LIT_BOOTINFO LDA ($EC),Y
         PHA
         INY
         CPY   #6
         BNE   LIT_BOOTINFO

                          ; RECUPERE LES INFOS EN PILE

         PLA              ; 6 - JMP(-)
         STA   $EE
         PLA              ; 5 - JMP(+)
         STA   $EF
         PLA              ; 4 - NB SECT
         TAY
         PLA              ; 3 - SECTEUR
         TAX
         PLA              ; 2 - BUF(+)-2
         STA   BUFHIGH
         PLA              ; 1 - PISTE
         JSR   GO
         BIT   DRIVEOFF
         JMP   ($00EE)    ; $EE(-) $EF(+)

* DONNEE POUR LE CHARGEMENT DU BOOT1

BOOT1INFO DFB  2          ; PISTE
         HEX   3E         ; BUF(+)-2
         DFB   1          ; SECTEUR
         DFB   9          ; NB SECT
         HEX   47         ; JMP(+)
         HEX   03         ; JMP(-)

******************* POINT D'ENTREE ******************

GO       STA   PISTE
         STX   SECTEUR
         STY   NB_SECTEUR
         LDA   BUFHIGH
         CLC
         ADC   NB_SECTEUR
         STA   BUFHIGH
         INC   BUFHIGH
         DEY
         BEQ   CALIBRAGE
H0860    INC   SECTEUR
         LDA   SECTEUR
         CMP   #$10
         BNE   H086E
         LDA   #$00
         STA   SECTEUR
         INC   PISTE
H086E    DEY
         BNE   H0860
CALIBRAGE LDX  #$60
         LDA   PISTE
         ASL
         STA   BUFLOW
H0878    LDA   H0478
         STA   $FD
         SEC
         SBC   BUFLOW
         BEQ   GESTIONLOAD
         BCS   H0889
         INC   H0478
         BCC   H088C
H0889    DEC   H0478
H088C    JSR   H08A2
         JSR   H08F2
         LDA   $FD
         AND   #$03
         ASL
         ORA   #$60
         TAY
         LDA   PHASEOFF,Y
         JSR   H08F2
         BEQ   H0878
H08A2    LDA   H0478
         AND   #$03
         ASL
         ORA   #$60
         TAY
         LDA   PHASEON,Y
         RTS
                          ;
GESTIONLOAD LDA #$00      ; IDENTIQUE AU TOM E. HAWK BOOT
         STA   BUFLOW
         LDY   SECTEUR    ; EQUIVALENCE SECTEUR LOGIQUE & PHYSIQUE
         LDA   DATASECT,Y
         STA   SECTEUR0
         LDX   #$60       ; CHARGE LE SECTEUR
         JSR   BOOT00
         DEC   SECTEUR    ; SECTEUR PRECEDENT
         BPL   H08C9
         LDA   #$0F       ; POSITIONNE SUR LE DERNIER SECTEUR
         STA   SECTEUR    ; DE LA PISTE PRECEDENTE
         DEC   PISTE
H08C9    DEC   BUFHIGH    ; MISE A JOUR BUFFER RECEPTION
         DEC   BUFHIGH
         DEC   NB_SECTEUR
         BNE   CALIBRAGE  ; ON N'A PAS FINI DE TOUT CHARGER
         RTS
                          ;
H08F2    LDA   #$28
         SEC
H08F5    PHA
H08F6    SBC   #$01
         BNE   H08F6
         PLA
         SBC   #$01
         BNE   H08F5
         RTS

DATASECT HEX   000D0B09070503010E0C0A080604020F
         LST   ON
         ASC   "DECKARD/HFC"
         LST   OFF